Fork of danielchc/amarr with Torznab action-name fix

Patched TorznabApi.kt to accept the hyphenated action names (movie-search, tv-search) that Caps.kt already advertises and that Radarr/Sonarr actually send, alongside the original non-hyphenated variants (movie, tvsearch). Upstream: https://github.com/danielchc/amarr
2026-09-07 23:54:47 +02:00
commit 42c70c5d1b
45 changed files with 9248 additions and 0 deletions
@@ -0,0 +1,66 @@
+plugins {
+    alias(libs.plugins.kotlin.jvm)
+    alias(libs.plugins.kotlin.serialization)
+    alias(libs.plugins.jib)
+    application
+}
+
+println("Version is $version")
+
+repositories {
+    mavenCentral()
+    mavenLocal()
+}
+
+dependencies {
+    implementation(libs.bundles.ktor.server)
+    implementation(libs.bundles.ktor.client)
+    implementation(libs.jamule)
+    implementation(libs.guava)
+    implementation(libs.logback)
+    implementation(libs.commons.text)
+
+    testImplementation(libs.bundles.kotest)
+    testImplementation(libs.mockk)
+    testImplementation(libs.ktor.server.test.host.jvm)
+    testImplementation(libs.ktor.client.mock)
+    testImplementation(libs.kotlin.test.junit)
+}
+
+java {
+    toolchain {
+        languageVersion.set(JavaLanguageVersion.of(17))
+    }
+}
+
+application {
+    mainClass.set("amarr.AppKt")
+}
+
+tasks.named<Test>("test") {
+    useJUnitPlatform()
+}
+
+jib {
+    from {
+        image = "eclipse-temurin:17-jre-ubi9-minimal"
+        platforms {
+            platform {
+                architecture = "amd64"
+                os = "linux"
+            }
+            platform {
+                architecture = "arm64"
+                os = "linux"
+            }
+        }
+    }
+    to {
+        image = "danielchc/amarr"
+        tags = setOf(version.toString())
+        auth {
+            username = System.getenv("DOCKER_USERNAME")
+            password = System.getenv("DOCKER_PASSWORD")
+        }
+    }
+}